ES:Argentina/Cultura/GLAM/Snippets

From OpenStreetMap Wiki
Jump to navigation Jump to search

tips and tricks & Howto's

Listar los museos con Overpass-turbo [https://overpass-turbo.eu/]

snippet
Ponerle límite a la consulta con un timeout de 25"
[timeout:25];
Devuelve los datos en JSON o XML
[out:json]
[out:xml]
Mapa de museos de CABA Normalmente haríamos esta consulta, que nos devuelve node, way y relation con sus elementos...
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out body; >; out skel qt;
Pero en varias ocasiones precisamos solo un par de coordenadas. Esto se aplica, por ejemplo, cuando necesitamos crear un mapa con uMap, cuando creamos un nodo en Wikidata, o cuando no podemos o necesitamos más detalles. 'out center' nos devuelve las coordenadas calculadas del centro del objeto.
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out center; >;
Devuelve los datos en CSV y nos da el total.


Nota: Esta consulta debe ser armada, detallando los campos requeridos; ver manual en: https://wiki.openstreetmap.org/wiki/Overpass_API/Overpass_QL#CSV_output_mode

[out:csv(::type,::id,"name","museum_type","wikidata",::count)];
area[name="Ciudad Autónoma de Buenos Aires"]->.a;
nwr(area.a)[tourism=museum];
out;
out count;
Ver en overpass-turbo una consulta (casi todos los campos) : https://overpass-turbo.eu/s/Jyg


En JOSM usar esta consulta (para que nos devuelva todos los nodos que componen las vías).
[out:csv(::type,::id,"name","museum_type","wikidata",::count)];
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out meta; >; out meta qt;

Devuelve los datos en CSV, con coordenadas para nwr y nos da el total de registros.
[out:csv(::type,::id,::lat,::lon,"name","addr:city",::count)];
area[name="Ciudad Autónoma de Buenos Aires"]->.a;
nwr(area.a)[tourism=museum];
out center;
out count;
Ver en overpass-turbo una consulta con más campos: https://overpass-turbo.eu/s/J4L
Buscar museos (cadena 'museo' dentro de 'name'), galerías y obras de arte (museum | artwork | gallery) duplicados o duplicados y sin nombres (dentro de los 50m) en Argentina.
area[name="Argentina"][admin_level=2][boundary=administrative]->.argentina;
(
 nwr(area.argentina)["tourism"~"(museum|artwork|gallery)"]->.a;
);
(
 nwr(around.a:50)[!tourism][name~"museo",i];  
 nwr(around.a:50)["tourism"~"(museum|artwork|gallery)"][!name];
);
(._;>;);
out meta;
Ver en overpass-turbo: https://overpass-turbo.eu/s/J4V
Lista los museos localizados en Colombia

https://overpass-turbo.eu/s/GN2

{{geocodeArea:colombia}}->.a; // Area a buscar
nwr[tourism=museum](area.a); // Consulta de etiqueta
out body; >; out skel qt; // Mostrar resultado
Para restringirte a tu área simplemente modifica el geocodeArea.
{{geocodeArea:caba}}->.varLugar;
{{geocodeArea:Provincia de Buenos Aires, Argentina}}->.varLugar2;
{{geocodeArea:San Luis, Argentina}}->.varLugar3;
{{geocodeArea:Bolivia}}->.varPais;
Lista los museos localizados dos localidades

https://overpass-turbo.eu/s/GN3

Ejemplo de Argentina, que tiene museos en la Antártida, por lo que se debe buscar en ambas
area[name="Argentina"][admin_level=2]->.lugar1;
nwr(area.lugar1)[tourism=museum];
out body; >; out skel qt;

area[name="Antártida Argentina"][boundary=region]->.lugar2;
nwr(area.lugar2)[tourism=museum];
out body; >; out skel qt;
Ver en overpass-turbo : https://overpass-turbo.eu/s/CXu
Lista los museos localizados en CABA sin acceso a sillas de ruedas ["wheelchair"="no"]

https://overpass-turbo.eu/s/GN4

{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum][wheelchair=no](area.ciudad);
out body; >; out skel qt;
Lista museos de CABA sin 'description'.
area(3601224652)->.a; 
nwr[tourism=museum](area.a)
  ["description"!~"."]; 
out body; >; out skel qt;
Variante usando 'geocodeArea'
{{geocodeArea:CABA}}->.a; 
nwr[tourism=museum](area.a)
  ["description"!~"."]; 
out body; >; out skel qt;

Lista los museos localizados de CABA, que sean museos de arte, que se encuentren en el CP C1425AAS y no tengan acceso a sillas de ruedas.

https://overpass-turbo.eu/s/GN5

{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum] [museum=art] ["addr:postcode"="C1425AAS"] [wheelchair=no](area.ciudad);
out body; >; out skel qt;
Lista los nodos, vías y/o relaciones localizados en Argentina 'operados' por la Dirección Nacional de Museos.

https://overpass-turbo.eu/s/GN6

{{geocodeArea:Argentina}}->.Pais;
nwr[operator="Dirección Nacional de Museos"](area.Pais);
out body; >; out skel qt;
Lista obras de arte exhibidas, principalmente, en museos de Argentina.

https://overpass-turbo.eu/s/GN7

[out:json][timeout:25];
      {{geocodeArea:Argentina}}->.a; 
      area[name="Argentina"][admin_level=2]->.lugar1;
(
  nwr["exhibit"] (area.a);
);
out body; >; out skel qt;
Buscar 'place' en la Antártida Argentina con ayuda de Wikidata
area[name="Antártida Argentina"][wikidata="Q646243"];
nwr (area) [place];
out body; >; out skel qt;
Nodos con por lo menos un tag (mayor a cero) en un área determinada por 'bbox'
node({{bbox}})(if:count_tags() > 0);
out body; >; out skel qt;
NodeWatRelation "tourism"="museum" con solo 2 tags
nwr({{bbox}})[tourism=museum](if:count_tags() == 2);
out body; >; out skel qt;
Variante : NodeWatRelation con un sólo 2 tags (es la opción 'i' para buscar mayúsculas y minúsculas)
nwr({{bbox}})["tourism"~"museum",i](if:count_tags() == 2);
out body; >; out skel qt;
Museo donde 'start_date' es mayor a 100 días.

https://overpass-turbo.eu/s/GN9

node["tourism"="museum"](if:date(t["start_date"])<date("{{date:100 days}}"))({{bbox}});
out body; >; out skel qt;
Selecciona los museos con un 'start_date' mayor a * días
node["tourism"="museum"][start_date~".*"](if:date(t["start_date"])<date("{{date:20000 days}}"))({{bbox}});
out body; >; out skel qt;
Selecciona los objetos que han sido añadidos o modificados más recientemente que la fecha.

https://overpass-turbo.eu/s/GNa

{{geocodeArea:argentina}}->.searchArea;
node["tourism"="museum"](newer:"2018-10-06T00:00:01")(area.searchArea);
out body; >; out skel qt;
Busca los 'NodeWayRelation' que el 'user' no editó pasado * tiempo
{{geocodeArea:Argentina}}->.searchArea;
((
  nwr[tourism=museum](area.searchArea);
); - /* este menos es para restar */
(
  nwr["tourism"="museum"](user:"martingggg")(newer:"2018-05-10T00:00:01")(area.searchArea);
););
out body; >; out skel qt;
Museos de Argentina sin [phone]
      {{geocodeArea:argentina}}->.a; 
      nwr[tourism=museum](area.a)
        ["phone"!~"."]; 
      out body; >; out skel qt;
variante
      area(3600286393)->.a; 
      nwr[tourism=museum](area.a)
        ["phone"!~"."]; 
      out body; >; out skel qt;
Consulta los (nwr) museos, pregunta si existe la etiqueta "opening_hours", si hay alguno que abra de 8 a 12:30 y por último pregunta si no tiene la etiqueta "wheelchair", en el área de la ventana actaual.

https://overpass-turbo.eu/s/GNb

nwr["tourism"="museum"]
  ["opening_hours"]
  ["opening_hours"!="08:30-12:30"] ({{bbox}})
  ["wheelchair"!~"."]; 
  out body; >; out skel qt;
Todos los museos del mundo ;-)

Esta query demanda muchos recursos por lo que quizá debieras incrementar el tiempo de ejecución. Prueba agregandole [timeout:50];

node["tourism"="museum"];
out body; >; out skel qt;
Si queres que sea compatible con Level0 o JOSM...
out body; >; out skel qt;
por
out meta; >; out meta qt;

Más snippets interesantes de OverPass Turbo

ID

Copiar y pegar tags, ideal para cuando tienes que pasar los tags de un nodo a una way: ;-)

Consultas varias con Wikidata Query Service (WQS) [https://query.wikidata.org/]

snippet
Listas los museos de Argentina con entradas en Wikidata
SELECT DISTINCT ?item ?name ?coord ?lat ?lon
WHERE {
   ?item wdt:P131* wd:Q414 .
   ?item wdt:P31/wdt:P279* wd:Q33506 .
   ?item wdt:P625 ?coord .
   ?item p:P625 ?coordinate .
   ?coordinate psv:P625 ?coordinate_node .
   ?coordinate_node wikibase:geoLatitude ?lat .
   ?coordinate_node wikibase:geoLongitude ?lon .
   SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
    ?item rdfs:label ?name
   }
}
ORDER BY ASC (?name)
Listas los museos de Argentina con entradas en Buenos Aires
SELECT ?item ?itemLabel ?coordinates WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q33506.
  ?item wdt:P131 wd:Q1486.
  ?item wdt:P625 ?coordinates.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es, en". }
}
Museos en Buenos Aires
SELECT DISTINCT ?item ?name ?coord ?lat ?lon ?URL_de_una_imagen_compatible_con_Commons WHERE {
  hint:Query hint:optimizer "None".
  ?item (wdt:P131*) wd:Q1486;
    (wdt:P31/(wdt:P279*)) wd:Q33506;
    wdt:P625 ?coord;
    p:P625 ?coordinate.
  ?coordinate psv:P625 ?coordinate_node.
  ?coordinate_node wikibase:geoLatitude ?lat;
    wikibase:geoLongitude ?lon.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?item rdfs:label ?name.
  }
  OPTIONAL { ?item wdt:P18 ?URL_de_una_imagen_compatible_con_Commons. }
}
ORDER BY (?name)
Museos en Instagram

Fuente: https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/Building_a_query/Museums_on_Instagram

    #defaultView:Map
SELECT ?item ?itemLabel ?instagram ?coordinates WHERE {
  ?item wdt:P31/wdt:P279* wd:Q33506 ;
        wdt:P2003 ?instagram ;
        wdt:P625 ?coordinates .
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}

Otros snippets Wikidata

Wikidata: SPARQL Tutorial