User:Ika-chan!/Overpass Turbo

Main article: Overpass Turbo

Overpass queries

Highways

Dual carriageways and frontage roads

It is best to search by region to reduce pressure on the browser.

try it yourself in overpass-turbo

[out:json][timeout:600];
(
  area["name:en"="Attica"]->.boundaryarea;
  way["highway"="motorway"](area.boundaryarea);
  way["dual_carriageway"="yes"](area.boundaryarea);
  way["frontage_road"="yes"](area.boundaryarea);
);
out geom qt;

{{style:
way{opacity:0.6;width:2.5}
way[highway=motorway]{color:#0000ff}
way[dual_carriageway=yes]{color:#008000}
way[dual_carriageway=yes][highway=~/.*_link/]{color:#00ff00}
way[frontage_road=yes]{color:#ff8000}
way[frontage_road=yes][highway=~/.*_link/]{color:#ff0000}
}}

Greek motorway concessions and operators

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.searchArea;
(
  node["marker"]["operator:type"="motorway"](area.searchArea);
  way["highway"]["operator"](area.searchArea);
);
out geom;

{{style:
node{symbol-fill-color:#000;symbol-fill-opacity:0.5;symbol-size:2;symbol-stroke-width:0}
way{color:#C0C0C0;opacity:1;width:2.5}
way[operator=Αυτοκινητόδρομος Αιγαίου]{color:#FF0000}
way[operator=Γέφυρα Α.Ε.]{color:#FF8000}
way[operator=Νέα Εγνατία Οδός]{color:#FFFF00}
way[operator=Κεντρική Οδός]{color:#00FF00}
way[operator=Μορέας]{color:#008000}
way[operator=Νέα Αττική Οδός]{color:#00FFFF}
way[operator=Νέα Οδός]{color:#0080FF}
way[operator=Ολυμπία Οδός]{color:#0000FF}
way[operator=Περιφέρεια Αττικής]{color:#800080}
}}

Greek road network relations

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.searchArea;
relation["network"~"^GR:(motorway|national(_old)?)$"](area.searchArea);
out geom;

{{style:
relation{opacity:0.6;width:2.5}
relation[network=GR:motorway]{color:#008000}
relation[network=GR:national][ref]{color:#0000ff}
relation[network=GR:national][ref:esye]{color:#0000ff}
relation[network=GR:national_old]{color:#0080ff}
}}

Greek road network relations not last edited by ika-chan!

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.greece;
relation["network"~"^GR:(motorway|national(_old)?)$"](area.greece)->.roads;
(.roads; - relation.roads(uid:4763179);)->.roads;
.roads out geom;

Greek road network relations proofreading

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.greece;
relation["network"~"^GR:(motorway|national(_old)?)$"](newer:"2026-07-18T07:40:00Z")(area.greece)->.roads;
(.roads; - relation.roads(uid:4763179);)->.roads;
.roads out geom;

Greek road numbers without a source

The first query finds motorway and national road numbers without a source. It does not include those that were merely renumbered (Α62, Α621 and Α64), and three ESYE numbers that are aliases of regular numbers (ΕΟ38β, ΕΟ65δ and ΕΟ9γ).

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.gr;
(
  way["highway"]["highway"!~"(construction|proposed)"]["ref"~"^(Α|ΕΟ)"]["source:ref"!~"^(Mapillary \\(2025-|Ministerial Decision|Register of National Roads)"](area.gr);
  way["highway"]["highway"!~"(construction|proposed)"]["old_ref"~"^(Α|ΕΟ)"]["old_ref"!~"^Α6(2|4)"]["source:old_ref"!~"^(Mapillary \\(2025-|Ministerial Decision|Register of National Roads)"](area.gr);
  way["highway"]["highway"!~"(construction|proposed)"]["ref:esye"]["ref:esye"!~"^ΕΟ(38β|65δ|9γ)$"]["source:ref:esye"!~"^(Ministerial Decision|Register of National Roads)"](area.gr);
);
out geom;

Tolls in Greece

This query returns road toll data in Greece: except for motorways, the default value is toll=no.

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.searchArea;
(
  node["barrier"="toll_booth"](area.searchArea);
  way["highway"~"^motorway.*"](area.searchArea);
  way["highway"]["toll"](area.searchArea);
  way["highway"]["toll:forward"](area.searchArea);
  way["highway"]["toll:backward"](area.searchArea);
);
out geom;

{{style:
  node{symbol-fill-color:#000;symbol-fill-opacity:1;symbol-size:2.5;symbol-stroke-width:0}
  way{color:#f00;opacity:0.6;width:2.5}
  way[toll:forward]{color:#0080ff}
  way[toll:backward]{color:#0080ff}
  way[toll=yes]{color:#0ff}
  way[construction=~/motorway(_link)?/][toll=no]{color:#050}
  way[construction=~/motorway(_link)?/][toll:forward][toll:backward]{color:#0a0}
  way[construction=~/motorway(_link)?/][toll=yes]{color:#0f0}
  way[highway=~/motorway(_link)?/][toll=no]{color:#050}
  way[highway=~/motorway(_link)?/][toll:forward][toll:backward]{color:#0a0}
  way[highway=~/motorway(_link)?/][toll=yes]{color:#0f0}
}}

Wizard queries

Highways

Main country	Description	Query
Greece	Find motorway or national road numbers that use non-Greek characters.	type:way and highway=* and ref~"(^|;)(A|E(O|Ο)|ΕO)" in Greece
Greece	Find one-way roads that are not tagged as dual carriageways or frontage roads.	type:way and highway~"^(trunk|primary|secondary|tertiary)$" and oneway=yes and dual_carriageway!=* and frontage_road!=* in Greece

Highways (old queries)

Elements last edited by Delta Evas ALL and sockpuppets

try it yourself in overpass-turbo

[out:json][timeout:600];
{{geocodeArea:Greece}}->.searchArea;
(
  nwr(user:"Map User Grecce")(area.searchArea);
  nwr(user:"GATAA RANA")(area.searchArea);
  nwr(user:"stratos008")(area.searchArea);
)->.useredit;
(.useredit; - node.useredit(if:count_tags() == 0);)->.useredit;
.useredit out geom;

Wizard queries

Main country	Description	Query
Greece	Trace a motorway.	type:way and highway=* and (ref~"(^|;)Α6(;|$)" or old_ref~"(^|;)Α6(;|$)") in Greece
Greece	Trace a national road.	type:way and highway=* and (ref~"(^|;)ΕΟ6(;|$)" or old_ref~"(^|;)ΕΟ6(;|$)") in Greece