Overpass API/Overpass QL

From OpenStreetMap Wiki
< Overpass API(Redirected from Overpass QL)
Jump to: navigation, search
Available languages — Overpass API/Overpass QL
Afrikaans Alemannisch aragonés asturianu azərbaycanca Bahasa Indonesia Bahasa Melayu Bân-lâm-gú Basa Jawa Baso Minangkabau bosanski brezhoneg català čeština dansk Deutsch eesti English español Esperanto estremeñu euskara français Frysk Gaeilge Gàidhlig galego Hausa hrvatski Igbo interlingua Interlingue isiXhosa isiZulu íslenska italiano Kiswahili Kreyòl ayisyen kréyòl gwadloupéyen kurdî latviešu Lëtzebuergesch lietuvių magyar Malagasy Malti Nederlands Nedersaksies norsk norsk nynorsk occitan Oromoo oʻzbekcha/ўзбекча Plattdüütsch polski português português do Brasil română shqip slovenčina slovenščina Soomaaliga suomi svenska Tiếng Việt Türkçe Vahcuengh vèneto Wolof Yorùbá Zazaki српски / srpski беларуская български қазақша македонски монгол русский тоҷикӣ українська Ελληνικά Հայերեն ქართული नेपाली मराठी हिन्दी অসমীয়া বাংলা ਪੰਜਾਬੀ ગુજરાતી ଓଡ଼ିଆ தமிழ் తెలుగు ಕನ್ನಡ മലയാളം සිංහල ไทย မြန်မာဘာသာ ລາວ ភាសាខ្មែរ ⵜⴰⵎⴰⵣⵉⵖⵜ አማርኛ 한국어 日本語 中文(简体)‎ 吴语 粵語 中文(繁體)‎ ייִדיש עברית اردو العربية پښتو سنڌي فارسی ދިވެހިބަސް
Overpass API logo.svg
Overpass API · Language reference · Language guide · Technical terms · Areas · Query examples · Advanced examples · Sparse Editing · Permanent ID · FAQ · more · Web site
Servers status · Versions · Development · Technical design · Installation · XAPI compatibility layer · Public transport sketch lines · Applications · Source code and issues
Overpass turbo · Wizard · Overpass turbo shortcuts · MapCSS stylesheets · Export to GeoJSON · more · Development · Source code and issues · Web site

Overpass QL (short for "Overpass Query Language") is the second query language created for the Overpass API; the first is Overpass XML.

Overpass QL is a procedural, imperative programming language written with a C style syntax. This document intends to be a complete reference to the structure of Overpass QL.

Contents

Language overview

Statements

Overpass QL source code is divided into statements, and every statement ends with a semicolon ;. Statements are executed sequentially by a process, and each statement run changes the process's execution state.

Execution state

The Overpass QL execution state consists of:

  • the default set _ (a single underscore)
  • other named sets, if created by the user
  • a stack, during the execution of Overpass QL block statements

Sets

Overpass QL manipulates sets. Statements write their results into sets, and sets are then read by subsequent statements as input. An Overpass QL set can contain any combination of – and any number of – OpenStreetMap nodes, ways, relations, and area elements.

Unless you specify a named set as an input or result, all input is implicitly read from (and all results are written to) the default set named _ (a single underscore). Once a new result is (implicitly or explicitly) assigned to an existing set, its previous contents will be replaced and are no longer available. Overpass QL sets always have global scope (visibility).

For example:

  node[name="Foo"];

implicitly writes the result of the tag query name="Foo" to the default set _, overwriting any previous contents with this result. A result can be written to a specific set using the -> syntax, when that set name is prefixed with .. The statement above is thus equivalent to:

  node[name="Foo"]->._;

Similarly, this statement:

 (
  node[name="Foo"];
  node[name="Bar"];
 );

combines the results of two tag queries with a union statement, then sends that result to the default set _. It is equivalent to:

 (
  node[name="Foo"];
  node[name="Bar"];
 )->._;

To write elements to a named set, again use the -> syntax, followed by the set name. For example, this query:

  (node[name="Foo"];)->.a;

will write all node elements with the tag name=Foo into the named set a. Set names may consist of letters, digits, and the underscore; however, they must not start with a digit. To read elements from a set, append . and the set name to the command.

  node.a[amenity=foo];

will return all nodes in the named set a that have the key amenity with the value foo.

Language structure

There are several different types of Overpass QL statements. They are grouped into:

  • Settings, which are optional, global variables, set in the first statement of the query. Examples of settings are the server timeout for the Overpass API server, and the output format of the Overpass QL query.
  • Standalone queries: These are complete statements on their own. They may perform functions such as querying the Overpass API server to create a set; manipulating the contents of an existing set; or sending the end results of a query to an output location.
  • Block statements: Block statements group Overpass QL statements together, to enable disjunctions (truth tests), as well as loops.

Standalone queries are themselves comprised of smaller Overpass QL language components, such as evaluators, filters, and operators.

Settings

Overpass QL settings must be declared in the first uncommented statement of the Overpass QL source code. Settings cannot be declared in multiple statements.

Settings declarations are enclosed in brackets []. A colon : appears between the setting name and the value or values to be set. The settings statement must be terminated with a semicolon ;.

// This is a typical settings declaration line
// on an Overpass Turbo server
[out:json][timeout:25];

timeout:

The timeout: setting has one parameter, a non-negative integer. Default value is 180.

This parameter indicates the maximum allowed runtime for the query in seconds, as expected by the user. If the query runs longer than this time, the server may abort the query with a timeout. The second effect is, the higher this value, the more probably the server rejects the query before executing it.

So, if you send a really complex big query, prefix it with a higher value; e.g., "3600" for an hour. And ensure that your client is patient enough to not abort due to a timeout in itself.

Example:

  [timeout:180]

Element limit (maxsize:)

The maxsize: setting has one parameter, a non-negative integer. Default value is 536870912 (512 MB).

This parameter indicates the maximum allowed memory for the query in bytes RAM on the server, as expected by the user. If the query needs more RAM than this value, the server may abort the query with a memory exhaustion. The second effect is, the higher this value, the more probably the server rejects the query before executing it.

So, if you send a really complex big query, prefix it with a higher value; e.g., "1073741824" for a gigabyte. The maximum value highly depends on the current server load, e.g. requests for 2GB will likely be rejected during peak hours, as they don't fit into the overall resource management. Technically speaking, maxsize is treated as a 64bit signed number.

Example:

  [maxsize:1073741824]

Important notice: Recently, a new mechanism was introduced to abort queries exceeding 2 GB of memory. This exact size of this limit is still under discussion and might change over time. If you experience error messages like "runtime error: Query run out of memory using about 2048 MB of RAM.", be sure to read this thread as well: http://permalink.gmane.org/gmane.comp.gis.openstreetmap.overpass/237

Output Format (out:)

The out: global setting is unrelated to the out statement. Syntax should not be mixed.

The out setting defines the output format used to return OSM data. It can take one of the five values; default value is xml:

  • xml
  • json (not to be confused with geoJSON)
  • csv
  • custom
  • popup

Example:

  [out:json]

CSV output mode

CSV output format returns OSM data as csv document, which can be directly opened in tools like LibreOffice. It requires additional configuration parameters to define a list of fields to display, as well as two optional parameters for adding/removing the CSV header line and changing the column separator.

Format:

  [out:csv( fieldname_1 [,fieldname_n ...] [; csv-headerline [; csv-separator-character ] ] )]

Notes:

  • Numeric values (coordinates, ids) uses no thousands separator, and uses the English dot (.) for the decimal separator (in geometric coordinates).
  • No escaping is made on for specific characters in string values. This will change with release 0.7.55.
  • The default separator character (tabulation) should still allow most of the time to parse the tabular data without missing/broken/misaligned columns.
  • These CSV defaults may still not match what your spreadsheet application expects (notably the decimal separator in non-English versions) if you open the CSV file directly with your application, and data could seem corrupted, or unparsable: instead, import the data in a text-only column of a new spreadsheet, and convert it to tabular data inside that application using your own settings; or use an external filter script to convert the file before opening it.

List of field names

Besides normal OSM field names (tags), special fields are available for each element in the result set to output. Note that all of these special field names need to be prefixed by two colons ::.

Special field name Description
::id OSM Object ID
::type OSM Object type: node, way, relation
::otype OSM Object as numeric value
::lat Latitude (available for nodes, or in out center mode)
::lon Longitude (available for nodes, or in out center mode)
The following meta information fields are only available if out meta; is used to output OSM elements.
::version OSM object's version number
::timestamp Last changed timestamp of an OSM object
::changeset Changeset in which the object was changed
::uid OSM User id
::user OSM User name
The following meta information fields are only available if out count; is used to output OSM elements.
::count Returns total number of objects (nodes, ways, relations and areas) in inputset
::count:nodes Returns number of nodes in inputset
::count:ways Returns number of ways in inputset
::count:relations Returns number of relations in inputset
::count:areas Returns number of areas in inputset

Example:

  [out:csv(
    ::"id", amenity, name, operator, opening_hours, "contact:website", "contact:phone", brand, dispensing, lastcheck
  )];

Railway stations in Bonn:

try it yourself in overpass-turbo
[out:csv(::id,::type,"name")];
area[name="Bonn"];
nwr(area)[railway=station];
out;

CSV header line

The presence or absence of a header line can be controled by the first optional parameter, which can be added right after the field list separated by semicolon. Possible values include true and false. If this parameter is not specified, a header line will be printed (i.e. its default value is true).

  [out:csv(
    ::"id", amenity, name, operator, opening_hours, "contact:website", "contact:phone", brand, dispensing, lastcheck;
    false
  )];

CSV separator character

By default all fields are separated by a tab character ("\t"). However, this setting can be changed via the second optional parameter. In the following example all output fields will be separated by a pipe ("|") character instead

  [out:csv(
    ::"id", amenity, name, operator, opening_hours, "contact:website", "contact:phone", brand, dispensing, lastcheck;
    true; "|"
  )];
Checking CSV output for complete data

Unlike other output modes like XML and JSON, there's currently no indication of any error message at all. An empty result (or a result with just a header line) might indicate either that nothing was found or that the query was aborted due to timeout or some other more serious error condition. One way to work around this is to introduce an additional counter, which summarizes the previous query result and is always put as the very last output statement of a query.

The following example extends the previously shown list of all railway stations in Bonn by an additional output statement returning an additional aggregated row in the CSV, describing a pseudo-element with type "count" and whose value will be in the last requested ::count column (whose value remains empty for normal data rows):

  [out:csv(::type,::id,"name",::count)];
  area[name="Bonn"]->.a;
  ( node(area.a)[railway=station];
    way(area.a)[railway=station];
    rel(area.a)[railway=station];
  );
  out;
  out count;

The output now includes an additional column with type ::count and an indication of how many total elements are contained in the current resultset: 5. If the final count line is missing or the total number differs, you know for sure that something went wrong and the query results are incomplete/inconsistent.

@type	@id	name	@count
node	26945519	Bonn-Oberkassel	
node	1271017705	Bonn-Beuel	
node	2428355974	Bonn-Bad Godesberg	
node	2713060210	Bonn Hauptbahnhof	
node	3400717493	Bonn-Mehlem	
count	0		5

The values custom and popup also require further configuration. Please see details in the output formats documentation.

Global bounding box (bbox)

The global bbox setting can define a bounding box that is then implicitly used in all statements (unless a statement specifies a different explicit bbox). The global bounding box default if no bbox is specified is "the entire world".

In a standard Overpass QL program, a bounding box is constructed with two decimal degree coordinate pairs in ISO 6709 standard order and format, and each value is separated with a comma. The values are, in order: southern-most latitude, western-most longitude, northern-most latitude, eastern-most longitude.

[bbox:south,west,north,east]
// A bbox framing the German city of Bonn
[bbox:50.6,7.0,50.8,7.3]
// A bbox framing part of Rio de Janeiro, Brazil
[bbox:-23,-43.1,-22.8,-43.3]

Note: When a query is URL encoded as the value of the data= parameter, a bounding box can also be appended as a separate bbox variable. When used this way, the order is reversed, lon-lat. (This is the common order for OpenLayers and other frameworks.)

The Bonn example, above, as used in a URL encoding:

  /api/interpreter?data=[bbox];node[amenity=post_box];out;&bbox=7.0,50.6,7.3,50.8

This finds all post boxes roughly in Bonn, Germany.

date

date is a global setting which modifies an Overpass QL query to examine attic data, and return results based on the OpenStreetMap database as of the date specified. This setting can be useful, for example, to reconstruct data that has been vandalized, or simply to view an object as it existed in the database at some point in the past.

It consists of the identifier date, followed by : and then an OpenStreetMap database standard ISO 8601 date enclosed in quotes, in the format YYYY-MM-DDThh:mm:ssZ.

This example queries the state of the database on 28th October 2015 at 19:20:00 UTC:

[date:"2015-10-28T19:20:00Z"]

There is no attic data in the OpenStreetMap database with a date earlier than 2012-09-12T06:55:00Z (1347432900 in epoch seconds). This date corresponds to the first change included in the ODbL compliant planet file. Use of an earlier date setting is technically possible, but doing so will always return the database state as of 2012-09-12T06:55:00Z.

Delta between two dates ("diff")

The diff setting lets the database determine the difference of two queries at different points in time. This is useful for example to deltas for database extracts.

It consists of the identifier diff, followed by : , an OpenStreetMap database standard ISO 8601 date enclosed in quotes, in the format YYYY-MM-DDThh:mm:ssZ , and optionally a comma and a second date. If only one date is given, then the second is assumed to be the current date ("now").

Example:

[diff:"2012-09-14T15:00:00Z"]

This processes the rest of the query as if it were posed on 14th September 2012 at 15:00, then processes the same query with current data and finally outputs the difference between the two results.

[diff:"2012-09-14T15:00:00Z","2012-09-21T15:00:00Z"]

Does basically the same, but compares the state of 14th September with the state of 21st September.

Note that the output does not include any intermediate versions, which might exist between the first and the last timestamp, i.e. if there are several changes on an object, only the last version in the given timeframe is returned.

Augmented Delta between two dates ("adiff")

The adiff does basically the same like "diff" , but for all elements that aren't contained in the newer result, it is indicated what happened to them.

If an element has been deleted, then its last deletion date is printed and the indication "visible=false". If an element has changed such that it no longer matches the query then its last change date is printed and the indication "visible=true".

For more information see: Augmented Diffs.

Block statements

Union

The union block statement is written as a pair of parentheses. Inside the union, any sequence of statements can be placed, including nested union and foreach statements. Note that the square brackets [ ... ] shown below indicate an optional part of the syntax and are not to be typed literally.

  (statement_1; statement_2; )[->.result_set];

The union block statement takes no input set. It produces a result set which is the union of the result sets of all sub-statements, regardless of whether a sub-statement has a redirected result set or not.

Example:

  (node[name="Foo"]; way[name="Foo"];);

The first statement collects all nodes that have a name tag "Foo"; the second statement collects all ways that have a name tag "Foo". After the union statement, the result set is the union of the result sets of both statements.

The result set of the union statement can be redirected with the usual postfix notation.

Example:

  (node[name="Foo"]; way[name="Foo"];)->.a;

This is the same as the preceding example, but the result is written into the variable a.

Limitation: Note that foreach and print statements cannot be sub-elements of element union.

Difference

The difference block statement is written as a pair of parentheses. Inside the difference statement, exactly two statements must be placed, separated by a minus sign. Note that the square brackets [ ... ] shown below indicate an optional part of the syntax and are not to be typed literally.

  (statement_1; - statement_2;)[->.result_set];

The difference block statement takes no input set. It produces a result set which contains all elements that are result of the first sub-statement and not contained in the result of the second sub-statement.

Example:

  (node[name="Foo"]; - node(50.0,7.0,51.0,8.0););

This collects all nodes that have a name tag "Foo" but are not inside the given bounding box.

The result set of the difference statement can be redirected with the usual postfix notation.

Example:

  (node[name="Foo"]; - node(50.0,7.0,51.0,8.0);)->.a;

This is the same as the preceding example, but the result is written into the variable a.

Intersection

It is also possible to produce a set of elements that appear in both of two input sets, i.e. elements that are part of both sets. This is described below in By input set (.setname):

  node.a.b;

This is not a block statement, but is listed here because of its close relation to the difference statement described above.

The block statement if

since v0.7.55

The block statement if executes its substatements only if its condition evaluates to boolean true. This allows e.g. to try more loosely search conditions if stricter search conditions did not deliver a result.

The statement does not directly interact with any sets.

The base syntax is

 if (<Evaluator>)
 {
   <List of Substatements>
 }

resp.

 if (<Evaluator>)
 {
   <List of Substatements>
 }
 else
 {
   <List of Substatements>
 }

where <Evaluator> is an evaulator and <List of Substatements> is a list of substatements.


For-each loop (foreach)

since v0.7.51

The foreach block statement is written as the keyword foreach, followed by a pair of curly braces. Any sequence of statements can be placed between these braces, including nested union and foreach statements.

The foreach block statement takes an input set and produces no result set. The foreach statement loops over the content of the input set, once for every element in the input set.

Example:

  way[name="Foo"];
  foreach
  {
    (
      ._;
      >;
    );
    out;
  }

For each way that has a name tag with value "Foo", this prints the nodes that belong to this way immediately followed by the way itself. In detail, the result set of way[name="Foo"] is taken as the input set. Then, for each element in this input set, the loop body is executed once. Inside the loop body, the union of the element and its nodes is taken. This union is then printed.

Note that during execution, each printed subset in an iteration is independent of subsets printed in other iterations, possibly resulting in duplicate objects in the global output (no union is computed by the out statement within the loop).

The input set of the foreach statement can be taken from a variable with the usual postfix notation:

Example:

  foreach.a(...);

This loops over the content of set a instead of the default set "_".

The name of the variable to put the loop element into can also be chosen by adding a postfix immediately before the opening parenthesis.

Example:

  foreach->.b(...);

This puts the element to loop over into the variable b. Without it, the foreach statement does not put the elements into any set.

Example for both input and loop set changed:

  foreach.a->.b(...);

Note that the input set can't be altered by the loop. Any updates to the set will be saved for further usage, but this will not alter the number of iterations.

The block statement for

since v0.7.55

The block statement for divides its input into subsets and executes all the statements in the loop body once for every subset.

The input set is broken down as follows: For each element the given evaluator is evaulated and elements with the same value are grouped together. At the beginning of each loop execution, the output set is filled with the relevant subset.

The base syntax is

 for (<Evaluator>)
 {
   <List of Substatements>
 }

The input and output set can be specified between for and the opening parenthesis, i.e. you set the input set

 for.<Name of Input Set> (<Evaluator>)
 {
   <List of Substatements>
 }

or the output set

 for->.<Name of Output Set> (<Evaluator>)
 {
   <List of Substatements>
 }

or both

 for.<Name of Input Set>->.<Name of Output Set> (<Evaluator>)
 {
   <List of Substatements>
 }

Within the loop, the value of the evaluator is available via the property val of the output set. I.e., with

 <Output Set>.val

you can access the value of the expression for this loop.

With the special evaluator keys(), one can loop over all the keys that exist in the subset. The respective subset for each key are the elements that have this key set. Unlike for a usual evaluator, the sets are not mutually distinct in that case.


The block statement complete

since v0.7.55

The block statement complete loops through its substatements until the results of the loop stabilize. This allows to track a group of loosely or tightly connected elements like all sections of a way with the same name or a system of tributary rivers.

The statement delivers the accumulated elements in its output set both at the beginning of each loop execution and as output of the whole statement.

The elements are accumulated from the input set before entering the loop and again from the input set at the end of the loop. If the input set contains extra elements then the loop is executed again.

The base syntax is

 complete
 {
   <List of Substatements>
 }

where <List of Substatements> is a list of substatements.

The maximum number of loops defaults to 4096. This value can be changed to any value between 1 and 1048576 for this loop. To do so, put the desired value in parentheses after the "complete" keyword:

 complete(<Number>)
 {
   <List of Substatements>
 }

The input and output set can be specified between complete and the opening parenthesis, i.e. you set the input set

 complete.<Name of Input Set>
 {
   <List of Substatements>
 }

or the output set

 complete->.<Name of Output Set>
 {
   <List of Substatements>
 }

or both

 complete.<Name of Input Set>->.<Name of Output Set>
 {
   <List of Substatements>
 }

resp.

 complete(<Number>).<Name of Input Set>->.<Name of Output Set>
 {
   <List of Substatements>
 }


The block statement retro

since v0.7.55

The block statement retro executes its substatements for the date given in the evaluator.

It is currently undefined whether the content of variables from outside the block is available within the block and vice versa. Future versions may transfer only derived elements, keep the environments completely apart, or morph elements from one point in time to the other.

The base syntax is

retro (<Evaluator>)
{
  <List of Substatements>
}

where <Evaluator> is an evaulator and <List of Substatements> is a list of substatements.

The block statement compare

since v0.7.55

The statement compare computes the diff of the data of two timestamps. That diff can consist of any elements as well as only those with specific properties.

The statement can have a block of substatements. The block of substatements is executed after computing the diff in the second run, once for the old timestamp and then again for the new timestamp. This allows to do extra computations based on the diff results.

The statement can only be used in diff mode. In other modes its behaviour is undefined, and in future versions it might be a syntax error to have it elsewhere.

In the first run of a diff query it returns an empty set. In the second run of a diff query it returns the difference of the elements. If the statement gets an evaluator as argument then only those elements that have different values on both timestamps are returned. If the element does not exist on one of the timstamps then its value is regarded as the empty string. Currently, the only purpose of such a difference is to feed it into an output statement.

The base syntax is

 compare();

In addition, an input and/or output set can be specified:

 .<Set> compare()->.<Set>;

With the evaluator, the syntax becomes

 compare(delta:<Evaluator>);

resp.

 .<Set> compare->.<Set>(delta:<Evaluator>);

In all syntax variants a block of substatements can be attached:

 compare()
 {
   <List of Substatements>
 };

resp.

 .<Set> compare(delta:<Evaluator>)->.<Set>;
 {
   <List of Substatements>
 };


Standalone queries

out

The out statement is unrelated to the out: global setting. Syntax should not be mixed.

The out statement outputs the contents of a set. It is almost always used in any Overpass QL query.

out count; is a statement which prints only the total counts of elements in the input set by type (nodes, ways, relations, areas). It cannot be combined with anything else.

The simplest form of the out statement has several implied defaults.

out;         // Simplest form of the out statement
._ out body; // Identical meaning to the above

The default input set _ can be overridden by prepending a period and a named set name to the out statement.

.mystuff out; // Output the named set 'mystuff'

The out statement can be configured with an arbitrary number of parameters that are appended, separated by whitespace, between the word out and the semicolon.

Allowed values, in any order, are:

  • One of the following for the degree of verbosity of the output; the default is body:
    • ids: Print only the ids of the elements in the set.
    • skel: Print the minimum information necessary for geometry. skel contains the id and coordinates for nodes; the id of a way and the ids of its member nodes; and for relations, the id of the relation, and the type, id, and role of all of its members.
    • body: Print all information necessary to use the data. These are also tags for all elements and the roles for relation members.
    • tags: Print only ids and tags for each element and not coordinates or members.
    • meta: Print everything known about the elements. meta includes everything output by body for each OSM element, as well as the version, changeset id, timestamp, and the user data of the user that last touched the object. Derived elements' metadata attributes are also missing for derived elements. The modificator noids lets all ids to be omitted from the statement.
  • One of the following modificators for geolocated information; default is to print none:
    • geom: Add the full geometry to each object. This adds coordinates to each node, to each node member of a way or relation, and it adds a sequence of "nd" members with coordinates to all relations.
    • bb: Adds only the bounding box of each element to the element. For nodes this is equivalent to "geom". For ways it is the enclosing bounding box of all nodes. For relations it is the enclosing bounding box of all node and way members, relations as members have no effect.
    • center: This adds only the center of the above mentioned bounding box to ways and relations. Note: The center point is not guaranteed to lie inside the polygon (example).
  • A bounding box in the format "(south,west,north,east)" (normally used with the geom verbosity type). In this case, only elements whose coordinates are inside this bounding box are produced. For way segments, the first or last coordinates outside this bounding box are also produced to allow for properly formed segments (this restriction has no effect on derived elements without any geometry).
  • One of the following for the sort order can be added. Default is asc:
    • asc: Sort by object id.
    • qt: Sort by quadtile index; this is roughly geographical and significantly faster than order by ids (derived elements generated by make or convert statements without any geometry will be grouped separately, only sorted by id).
  • A non-negative integer, which limits the output to a maximum of the given number. If not specified, the entire set will be output.

Item

The item standalone query consists only of an input set prefix.

It takes the input set specified by its prefix. This is in particular useful for union statements: it reproduces its input set as (part of the) result of the union statement.

The most common usage is the usage with the default input set, _, as shown below.

  ._;

The following union statement will join all items in the default input set with the default input set's recurse down result. It will then output the result back to the default input set, overwriting it.

  (._; >;);

But of course other sets are possible too:

  .a;

In the context of a union statement:

  (.a; .a >;);

Note: Subsequent statements in a union statement are not impacted by the item statement. In particular, .a; does not add the contents of the input set to _, the default item set.

The item statement can also be used as a filter.

Recurse up (<)

The recurse up standalone query is written as a single less than symbol, "<".

It takes an input set. It produces a result set. Its result set is composed of:

  • all ways that have a node which appears in the input set; plus
  • all relations that have a node or way which appears in the input set; plus
  • all relations that have a way which appears in the result set

Example:

  <;

The input set of the recurse up statement can be chosen with the usual prefix notation:

  .a <;

The result set of the recurse up statement can be redirected with the usual postfix notation:

  < ->.b;

Of course, you can also change both:

  .a < ->.b;

Recurse up relations (<<)

The recurse up relations standalone query has a similar syntax to the recurse up query and differs only in two aspects:

  • It is written as a double less than.
  • It also recursively returns all relations that have a member relation appearing in the input set.

In particular, you can change the input and/or result set with the same notation as for the recurse up standalone query.

Precisely, the recurse up relations standalone query returns the transitive and reflexive closure of membership backwards.

Example:

  <<;

Recurse down (>)

The recurse down standalone query is written as a single greater than.

It takes an input set. It produces a result set. Its result set is composed of:

  • all nodes that are part of a way which appears in the input set; plus
  • all nodes and ways that are members of a relation which appears in the input set; plus
  • all nodes that are part of a way which appears in the result set

In particular, you can change the input and/or result set with the same notation as for the recurse up standalone query.

Example:

  >;

Recurse down relations (>>)

The recurse down relations standalone query has a similar syntax to the recurse down query and differs only in two aspects:

  • It is written as a double greater than.
  • It also recursively returns all relations that are members of a relation appearing in the input set.

In particular, you can change the input and/or result set with the same notation as for the recurse down standalone query.

Precisely, the recurse down relations standalone query returns the transitive and reflexive closure of membership.

Example:

  >>;

Query for areas (is_in)

The standalone query is_in returns the areas that cover

  • the given coordinates (when specified) or
  • one or more nodes from the input set (when no coordinates are specified).

It takes either an input set or a coordinate and produces a result set. The results are all areas which contain at least one of node from the input set or the specified coordinates.

is_in cannot be directly used with any of the Overpass QL filters. For filtering the is_in result, a further query is needed (see below): the [square brackets] shown below, indicate optional parts and are not part of the syntax to type.

  [.input_set] is_in         [-> .result_set];
  is_in(latitude, longitude) [-> .result_set];

In its shortest form, it takes its input set as the coordinates to search for. Example:

  is_in;

The input set can be chosen with the usual prefix notation:

  .a is_in;

The result set can be redirected with the usual postfix notation:

  is_in->.b;

Of course, you can also change both:

  .a is_in->.b;

Instead of taking existing nodes you can also specify coordinates with two floating point numbers, divided by a comma. They are interpreted as latitude, longitude. In this case, the input set is ignored. Example:

  is_in(50.7,7.2);

Also in this variant, the result set can be redirected with the usual postfix notation:

  is_in(50.7,7.2)->.b;

Area creation depends on some specific extraction rules, there's no area counterpart for each and every OSM way or relation! For more details see areas.osm3s and the Areas Wiki page.

To filter the result returned by is_in by additional filter criteria, an additional query is needed:

  is_in(48.856089,2.29789);
  area._[admin_level="2"];     // ._ represents the default inputset, which contains all areas returned by ''is_in''

The statement timeline

since v0.7.55

The statement timeline takes type and id of an object and optionally version as arguments. It then returns a derived structure containing the meta information of the specified version. If no version is specified then one object for each known version is returned. Each of these objects has tags ref, reftype, and refversion to identify the reference. In addition, it has tags created and expired that contain the relevant timestamps.

The base syntax is

 timeline(<Type>, <Ref>);

resp.

 timeline(<Type>, <Ref>, <Version>);

where <Type> is one of the three literals node, way, or relation.

In addition, an output set <Set> can be specified:

 timeline(<Type>, <Ref>)->.<Set>;

resp.

 timeline(<Type>, <Ref>, <Version>)->.<Set>;


The statement local

since v0.7.55

The statement local converts the given input into the localized representation of OSM data. The output parameter controls which classes of data are included.

Without a type parameter local delivers geometry and tags. This is one object per tagged node plus one object per part of a way plus one object per part of a relation geometry.

With the type parameter "ll", it delivers additionally loose objects. There are one object per way with tags but without node members and one object per relation member of any relation without node or way members.

With the type parameter "llb", it delivers even more data: It delivers the objects that associate the OSM element ids to the aforementioned objects.

The base syntax is

 local <Type>

where <Type> is empty, "ll", or "llb". You can also specify other input and/or output sets than "_":

 .<Set> local <Type> ->.<Set>

The first set is the input set, the second set is the output set.


The statement convert

since v0.7.54

The statement convert produces per element in its input set one derived element. The content of this output element is controlled by the parameters of the statement.

It is necessary to set a fixed type as type for all the generated elements. After that, an arbitrary number of tags can be set. In addition, it can be specified to copy all keys from the originating object. In this case, it is also possible to selectively suppress some tags.

Finally, it is possible to explicitly set the id of the generated objects. If you do not set an id then an unique id from a global ascending counter is assigned.

The base syntax is

 convert <Type> <List of Tags>

where <List of Tags> is a comma separated list of items, each of which must be one the following

 <Key> = <Evaluator>
 ::id = <Evaluator>
 :: = <Evaluator>
 !<Key>


The statement make

since v0.7.54

The statement make produces per execution one derived element. The content of this output element is controlled by the parameters of the statement.

It is necessary to set a fixed type as type for the generated element. After that, an arbitrary number of tags can be set.

As opposed to the convert statement, setting a generic key requires to prepend with the name of a set. At execution time, a make statement with a generic key sets tags for all keys that appear at least once in any of the elements from the chosen set. Explicitly defined tags always override keys generated by the generic key mechanism. Similarly, explicitly with a shrek canceled tags are skipped by the generic key mechanism.

Finally, it is possible to explicitly set the id of the generated object. If you do not set an id then an unique id from a global ascending counter is assigned.

The base syntax is

 make <Type> <List of Tags>

where <List of Tags> is a comma separated list of items, each of which must be one the following

 <Key> = <Evaluator>
 <Set>:: = <Evaluator>
 !<Key>
 ::id = <Evaluator>

It is a syntax error to set the same key twice. Also, at most one generic key can be set.

The Query Statement

The most important statement is the query statement. This is not a single statement but rather consists of one of the type specifiers node, way, relation (or shorthand rel), derived, area, or nwr (shorthand for nodes, ways or relations) followed by one or more filters. The result set is the set of all elements that match the conditions of all the filters.

Example:

// one filter
  node[name="Foo"];
  way[name="Foo"];
  rel[name="Foo"];
  nwr[name="Foo"];
  derived[name="Foo"];
  area[name="Foo"];

// many filters
  node[name="Foo"][type="Bar"];

Here, node, way, rel, nwr, derived, and area are the type specifier, [name="Foo"] resp. [type="Bar"] is the filter and the semicolon ends the statement.

The query statement has a result set that can be changed with the usual postfix notation.

  node[name="Foo"]->.a;

The individual filters may have in addition input sets that can be changed in the individual filters. Please see for this at the respective filter.


The Query Filter

The query filter can be added as condition to a query statement. It has an evaluator as argument and it lets pass only those elements for which the expression returns boolean true.

At the moment, the query filter cannot be the only condition in a query. This is due to implementation reasons and will change in future versions.

It is technically possible to have multiple query filters in a single query. But it does not make sense: Their evaulators can be combined with a conjunction in a single query filter. This has the same semantics and is faster.

Its syntax is

 (if: <Evaluator>)

The whitespace is optional.

Filters

By tag (has-kv)

The has-kv filter selects all elements that have or have not a tag with a certain value. It supports the basic OSM types node, way, and relation as well as the extended type area.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

All variants consist of an opening bracket, then a string literal in single or double quotes. Then the variants differ. All variants end with a closing bracket. If the string literal consists only of letters, the quotes can be omitted.

Equals (=, !=)

The most common variant selects all elements where the tag with the given key has a specific value. This variant contains after the key literal an equal sign and a further literal containing the value. Examples, all equivalent:

  node["name"="Foo"];
  node[name=Foo];
  node['name'="Foo"];
  node[name="Foo"];
  node["name"='Foo'];

If you have a digit, whitespace or whatever in the value, you do need single or double quotes:

  node["name"="Foo Street"];
  node["name"='Foo Street'];
  node[name="Foo Street"];

Querying for empty values is not possible using the equals value operator. This can only be achieved by using a regular expression:

node[power=""];          // not supported
node[power~"^$"];        // use regular expression instead

Likewise, querying empty key values is also not possible using this kind of key-value query and needs to be expressed via regular expressions.

node[~"^$"~"."];         // find nodes with empty key ("") and any value

NB: Overpass Turbo Wizard already has some logic in place to automatically convert ""="" accordingly.

Exists

The second variant selects all elements that have a tag with a certain key and an arbitrary value. It contains nothing between the key literal and the closing bracket:

  node["name"];
  node['name'];
  node[name];

Not exists

since v0.7.53

This variant selects all element, that don't have a tag with a certain key and an arbitrary value.

  node[!"name"];
  node[!'name'];
  node[!name];

In previous versions, 'not exists' had to be written as node["name"!~".*"];.

Value matches regular expression (~, !~)

The third variant selects all elements that have a tag with a certain key and a value that matches some regular expression. It contains after the key literal a tilde, then a second literal for the regular expression to search for:


Statement Explanation
node["name"~"^Foo$"]; Finds nodes, where the tag name matches exactly Foo - identical to node["name"="foo"];
node["name"~"^Foo"]; Finds nodes, where the tag name starts with Foo
node["name"~"Foo$"]; Finds nodes, where the tag name ends with Foo
node["name"~"Foo"]; Finds nodes, where the tag name contains the substring Foo anywhere in the tag value
node["name"~".*"]; Finds nodes, where the tag name matches anything, equal to node["name"];
node["name"!~".*"]; Finds nodes without name tag; does not have key name - identical to node[!"name"];


Please note that in QL you need to escape backslashes: ["name"~"^St\."] results in the regular expression ^St. (which finds every name starting with "St"), while ["name"~"^St\\."] produces the most likely meant regular expression St\. (which finds every name starting with "St."). This is due to the C escaping rules and doesn't apply to the XML syntax.

Case insensitively

You can also search case insensitively

  node["name"~"^Foo$",i];    /* finds "foo", "FOO", "fOo", "Foo" etc. */

Both the key and value variants with and without regular expressions can be negated. They then select exactly the elements which have a tag with the given key, but no matching value and the elements that don't have a tag with the given key:

  node["name"!="Foo"];
  node["name"!~"Foo"];
  node["name"!~"Foo",i];

Key/value matches regular expression (~"key regex"~"value regex")

The fourth variant selects all elements where both key and value match a regular expression. After an initial tilde (~) the regular expression for the key needs to be provided, followed by another tilde character and eventually the regular expression for the value.

  node[~"^addr:.*$"~"^Foo$"];    /* finds addr:* tags with value exactly "Foo" */
  node[~"^addr:.*$"~"^Foo"];     /* finds addr:* tags with value starting with "Foo" */
  node[~"^addr:.*$"~"Foo$"];     /* finds addr:* tags with value ending with "Foo" */
  node[~"^addr:.*$"~"Foo"];      /* finds addr:* tags with value containing the substring "Foo" */
  node[~"^addr:.*$"~"."];        /* finds addr:* tags with any value */
  node[~"^name(:.*)?$"~"."];     /* finds anything with a name or name:lang tag, and with any value */
  node[~"^name(:ar|:he)?$"~"."]; /* finds anything with name, name:ar, or name:he tag, and with any value*/

This format also supports case-insensitive searches: node[~"^addr:.*$"~"^Foo$",i];. Case-insensitivity applies to both tag key and value searches in this case.

Bounding box

The bounding box query filter selects all elements within a rectangular bounding box.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

  (south,west,north,east)

It consists of an opening parenthesis. Then follow four floating point numbers, separated by commas. The filter ends with a closing parenthesis.

The floating point numbers give the limits of the bounding box: The first is the southern limit or minimum latitude. The second is the western limit, usually the minimum longitude. The third is the northern limit or maximum latitude. The last is the eastern limit, usually the maximum longitude. If the second argument is bigger than the fourth argument, the bounding box crosses the longitude of 180 degrees.

Example:

  node(50.6,7.0,50.8,7.3);

Recurse (n, w, r, bn, bw, br)

The recurse filter selects all elements that are members of an element from the input set or have an element of the input set as member, depending on the given parameter.

The input set can be changed with an adapted prefix notation. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows one of the symbols: w (forward from ways), r (forward from relations), bn (backward from nodes), bw (backward from ways), or br (backward from relations). Then follows an optional input set declaration. The filter ends with a closing parenthesis.

Examples with default input set:

  node(w);            // select child nodes from ways in the input set
  node(r);            // select node members of relations in the input set
  way(bn);            // select parent ways for nodes in the input set
  way(r);             // select way members of relations in the input set
  rel(bn);            // select relations that have node members in the input set
  rel(bw);            // select relations that have way members in the input set
  rel(r);             // select relation members of relations in the input set
  rel(br);            // select parent relations from relations in the input set

Example with modified input set:

  node(w.foo);        // select child nodes from ways in the "foo" input set

You can also restrict the recurse to a specific role. Just add a colon and then the name of the role before the closing parenthesis.

Examples with default input set:

  node(r:"role");     // select node members of relations in the input set
  way(r:"role");      // select way members of relations in the input set
  rel(bn:"role");     // select relations that have node members in the input set
  rel(bw:"role");     // select relations that have way members in the input set
  rel(r:"role");      // select relation members of relations in the input set
  rel(br:"role");     // select parent relations from relations in the input set

Example with modified input set:

  node(r.foo:"role"); // select node members with role "role" of relations in the "foo" input set

And you can also search explicitly for empty roles:

  node(r:"");         // select node members with empty role of relations in the input set
  node(r.foo:"");     // select node members with empty role of relations in the "foo" input set

By input set (.setname)

The "item" filter selects all elements from its input set.

As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of a dot, followed by the name of the input set.

Examples: The default set:

  node._;

and a named set:

  node.a;

It is also possible to specify several input sets (set intersection). For example:

  node.a.b;
This statement returns all nodes which are both in input set .a and input set .b.

By element id

The id-query filter selects the element of given type with given id. It supports beside the OSM datatypes node, way, and relation also the type area.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows a positive integer. The filter is ends with a closing parenthesis.

Examples:

  node(1);
  way(1);
  rel(1);
  area(1);

Note that area ids need to be derived from an existing OSM way by adding 2400000000 to its OSM id or in case of a relation by adding 3600000000 respectively. Note that area creation is subject to some extraction rules, i.e. not all ways/relations have an area counterpart. See areas.osm3s for details.

Since version 0.7.54, the id-query filter also supports multiple values. To avoid conflicts with the bounding box filter, a new mandatory id: prefix has to be used in this case.

   node(id:1000,1001,1002,1003,1004,1005);
   way(id:3998029,3998240,4065354,4065364,4065392,4065421);
   rel(id:10815,10816);
   area(id:1234);

Performance hint: Try to bundle multiple id queries into one statement, i.e. instead of writing (way(3998029);way(3998240);way(4065354);); use way(id:3998029,3998240,4065354);

Relative to other elements (around)

The around filter selects all elements within a certain radius around the elements in the input set. If you provide coordinates, then these coordinates are used instead of the input set. The input set can be changed with an adapted prefix notation. As for all filters, the result set is specified by the whole statement, not the individual filter.

A radius of 0 can be used for a way intersection test on outer/inner points.

Syntax: It consists of an opening parenthesis. Then follows the keyword around. Then follows optionally an input set declaration. Then follows a single floating point number that denotes the radius in meters. The filter either ends with a closing parenthesis or is followed by two comma separated floating point numbers indicating latitude and longitude and then finally a closing parenthesis.

  (around[.input_set]:radius)
  (around:radius,latitude,longitude)

Since version 0.7.55, it is possible to query for all elements which are within a certain radius of a given linestring, which is given by a list of lat/lon pairs:

  (around[.input_set]:radius)
  (around:radius,latitude_1,longitude_1,latitude_2,longitude_2,...,latitude_n,longitude_n)

Example:

  node(around:100.0);
  way(around:100.0);
  rel(around:100.0);

Example with modified input set:

  node(around.a:100.0);

Example with coordinates:

  node(around:100.0,50.7,7.1);
  way(around:100.0,50.7,7.1);
  rel(around:100.0,50.7,7.1);

Example with linestring:

try it yourself in overpass-turbo
way[highway](around:500,50.540853270068986,8.048780365649707,50.53106288705902,8.030823236553783,50.51780737956311,8.019643105996508,50.50287491071276,8.016749912560886,50.48828159051387,8.022534398052139,50.47599950382573,8.036215335651725,50.467689755650376,8.055945038928135,50.46447690759688,8.079058902127825,50.46679590711731,8.102435269947343,50.47433280529453,8.122917034379736,50.48606755168466,8.137738019645033,50.50041288059356,8.144896569557243,50.51542994506574,8.143425882283827,50.529090915610794,8.13352458229042,50.53955268865336,8.11652989500613,50.545404823255616,8.09473704711951,50.545858734919165,8.07108928349599,50.540853270068986,8.048780365649707)   
;(._;>;);out meta;

For further use cases, see: https://www.openstreetmap.org/user/mmd/diary/42055

Example: Find all cinema nodes in Bonn which are at most 100m away from bus stops

try it yourself in overpass-turbo
area[name="Bonn"];
node(area)[highway=bus_stop];
node(around:100)[amenity=cinema];
out;

Find both cinema nodes and ways in Bonn, which are at most 100m away from bus stop nodes:

try it yourself in overpass-turbo
area[name="Bonn"];
node(area)[highway=bus_stop]->.bus_stops;
( 
  way(around.bus_stops:100)[amenity=cinema];
  node(around.bus_stops:100)[amenity=cinema];
);
(._;>;);
out meta;

By polygon (poly)

The polygon filter selects all elements of the chosen type inside the given polygon.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows the keyword poly. Then follows a string containing an even number of floating point numbers, divided only by whitespace. Each pair of floating point numbers represents a coordinate, in order latitude, then longitude. The filter ends with a closing parenthesis:

  (poly:"latitude_1 longitude_1 latitude_2 longitude_2 latitude_3 longitude_3 …");

An example (a triangle near Bonn, Germany):

  node(poly:"50.7 7.1 50.7 7.2 50.75 7.15");
  way(poly:"50.7 7.1 50.7 7.2 50.75 7.15");
  rel(poly:"50.7 7.1 50.7 7.2 50.75 7.15");

Performance hint: A large number of latitude/longitude pairs slows down the (poly: ) filter, hence simplifying the polyline geometry before using it in a poly filter is recommended.

newer

The newer filter selects all elements that have been changed since the given date. As opposed to other filters, this filter cannot be used alone. If the underlying database instance supports attic data and the date difference is at most one month, then "changed" is probably a better choice than "newer".

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows a date specification. Please note that this date specification cannot be abbreviated and has to be put in single or double quotes. The filter ends with a closing parenthesis.

Example:

  node._(newer:"2012-09-14T07:00:00Z");
This finds all nodes that have changed since 14 Sep 2012, 7 h UTC, in the given input set.

By date of change (changed)

The changed filter selects all elements that have been changed between the two given dates. If only one date is given, then the second is assumed to be the front date of the database. If only one date is given and it is run with the current timestamp, then it behaves exactly like "newer" with two exceptions: first, it is faster (see note), second, it can also stand as the only filter.

Note: As of June 2017, a known bug can cause "changed" to be much slower than "newer" in some cases. Consider using "newer" until it is resolved, or consider testing which one runs faster for you. See the following Github issues: #278, #322, #346. See this discussion too.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows a date specification. Please note that this date specification cannot be abbreviated and has to be put in single or double quotes. Then can follow a comma and a second date specification. The filter ends with a closing parenthesis.

Example: All changes since the given date and now

  node._(changed:"2012-09-14T07:00:00Z");

Example: All changes between the two given dates

  node._(changed:"2012-09-14T07:00:00Z","2012-09-14T07:01:00Z");

By user (user, uid)

The user filter selects all elements that have been last touched by the specified user.

It has no input set. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows either the keyword user, a colon and a string literal denoting the user name to search for. Or the keyword uid followed by the user id of the user to search for. The filter ends with a closing parenthesis.

Example:

  node(user:"Steve");
  node(uid:1);

Since release 0.7.53 it is also possible to specify multiple user names:

  node(user:"Mapper1","Mapper2","Mapper 3");
  node(uid:1,2,4,8,16);

By area (area)

The area filter selects all elements of the chosen type that are inside the given area. Please note with regard to attic data that areas always represent current data.

The input set can be changed with an adapted prefix notation. As for all filters, the result set is specified by the whole statement, not the individual filter.

Syntax: It consists of an opening parenthesis. Then follows the keyword area. Then can follow a colon and a non-negative integer. The filter ends with a closing parenthesis.

Nodes are found if they are properly inside or on the border of the area. Ways are found if at least one point (also points on the segment) is properly inside the area. A way ending on the border and not otherwise crossing the area is not found. Relations are found if one of its members is properly inside the area.

If the area statement is provided without integer, the areas from the input set are used. An example:

  node(area);
  way(area);
  rel(area);

The example with modified input set:

  node(area.a);
  way(area.a);
  rel(area.a);

If an integer is added, the input set is ignored and instead the area that has the given integer as id is taken. For example:

  node(area:2400000001);
  way(area:2400000001);
  rel(area:2400000001);

Caveat: area(area); is currently not supported. In this case, the (area) filter will be silently ignored, leading to unexpected results.

Because areas in OSM are not native elements but are only inferred from the OSM database using its closed ways or relations; this facility allows grouping their various representation in a coherent set which can store their geometry, independently of their complexity and representation in the OSM database, as if they were a single distinctive element, without using complex filtering rules in your query. However associating these objects with an OSM id attribute requires some adjustment because the same id value could be used for unrelated elements with different type (way or relation). For this reason, areas returned by the Overpass API only have a "virtual" id specific to the Overpass API, but not found directly in the OSM database.

By convention the area id can be calculated from an existing OSM way by adding 2400000000 to its OSM id, or in case of a relation by adding 3600000000 respectively. Note that area creation is subject to some extraction rules, i.e. not all ways/relations have an area counterpart (notably those that are tagged with area=no, and most multipolygons and that don't have a defined name=* will not be part of areas).

Areas are created by a regular job on the Overpass API server and usually have a lag of several hours compared to the OSM main database. The exact timestamp can be determined by checking the `timestamp_areas_base` value in the Overpass json or xml result.

If you want more immediate results (not depending on the delayed batch processing), you can also write your own filters without using this facility in your Overpass query: use standard OSM element types and ids and filter them by specific tags of your choice.

See areas.osm3s for details of the filters (written using the XML variant of the Overpass query language) currently by Overpass used to generate the areas that can be queried with this facility. Those areas are defined using the "pivot" query feature (see below).

Area pivot (pivot)

The pivot filter selects the element of the chosen type that defines the outline of the given area.

The input set can be changed with an adapted prefix notation. As for all filters, the result set is specified by the whole statement, not the individual filter.

It consists of an opening parenthesis. Then follows the keyword pivot. The filter ends with a closing parenthesis.

The statement finds for each area in the input set the respective element(s) that the area has been generated from. This will either be a multipolygon relation or a way.

Examples:

// These use the default input set '_'
way(pivot);
rel(pivot);
// These use the input set 'a'
way(pivot.a);
rel(pivot.a);

The following example determines the area(s) for the county of Greater London, and stores the result in the set londonarea. In the next statement, the areas contained in the londonarea set are converted back into their corresponding OSM relations using the pivot filter. Finally, out geom; outputs the relations (including their child ways and nodes).

area[name="London"][admin_level=6][boundary=administrative]->.londonarea;
rel(pivot.londonarea);
out geom;

Conditional query filter (if:)

since v0.7.54

The query filter can be added as condition to a query statement. It has an evaluator as argument and it lets pass only those elements for which the expression returns boolean true.

At the moment, the query filter cannot be the only condition in a query. This is due to implementation reasons and will change in future versions.

It is technically possible to have multiple query filters in a single query. But it does not make sense:

  • Their evaluators can be combined with a conjunction in a single query filter.
  • This has the same semantics and is faster.

Its syntax is:

 (if: <Evaluator>)

The whitespace is optional.

Many filters above can be generalized using conditional query filter, if one needs more specific conditions for filter the objects in the query input set. For example, the query:

  node[name=foo];

is equivalent to the following one using a conditional query filter (but for simplicity the former syntax using simpler a filter by tag value is still recommended, as it may have better performance on the Overpass server, and because the new syntax for evaluators may still not be supported in the current implementation of Overpass servers and client libraries before version 0.7.54 of the API):

  node(if: t["name"] == "foo");


Evaluators

Evaluators are functions internal to Overpass QL that return a value when executed. The values returned can be used to manipulate results in query statements through many means, such as:

  • Getting statistical information about query results
  • Filtering for elements matching specific criteria
  • Adding or removing tags from elements.

Numerous evaluator types exist, including those for tags, element counts, element metadata, timestamps, and geometry of an element.

The following types of evaluators exist and are explained further down:

  • Const evaluators deliver always the same value independent of context.
  • Element dependent evaluators deliver information about an individual object.

They only make sense in the context of a single element.

  • Statistical evaluators deliver information about a set as a whole.
  • Aggregators let an element dependent evaluator loop over all elements of a set and combine its results.
  • Operators and endomorphisms combine the result of one or two evaluator executions into a new result.

Literals

Literals represent fixed values, and can be used for comparisons and tests against operators, and as arguments to evaluators. Examples of literals:

Literal Explanation
3 The whole number value 3 †*
3.14159 The floating point number 3.14159 †*
2017-09-28T19:51:44Z An ISO 8601 timestamp, in the format in common use in the OpenStreetMap database.

The format is YYYY-MM-DDThh:mm:ssZ. ‡

London Bridge A string of characters ‡
addr:housenumber A string representing a commonly used OpenStreetMap key, addr:housenumber

† Integers and floating point numbers treated as numbers and expressed as less than zero (e.g -1.3) are not themselves literals. They are literals modified with the unary minus operator.

* Some positive and negative integer and floating point numbers, (such as when used in the context of the bounding box query filter), are interpreted as strings.

‡ It is generally wise to include quotes around these literals, to avoid the possibility of characters like : - or whitespace being incorrectly interpreted by an evaluator. For example, "London Bridge" and "addr:housenumber" avoids parsing issues inside tag evaluators. "2017-09-28T19:51:44Z" is a safe way to write a timestamp literal.

Some functions, such as date(), will attempt to type cast a literal into a standard format suitable for Overpass QL.

Element Dependent Operators

Element dependent operators require one or zero parameters. Their syntax varies, but most have the appearance of a function name plus parentheses, like is_closed().

They can only be called in a context where elements are processed. This applies to convert, to filter, or to arguments of aggregate functions. They cannot be called directly from make.


Id and Type of the Element

The operator id returns the id of the element. The operator type returns the type of the element. Both operators take no parameters.

The syntax is

 id()

resp.

 type()


Closedness

The operator is_closed returns whether the element is a closed way. The operator is undefined for any other type of element. For ways, it returns "1" if the first member of the way is equal to the last member of the way and "0" otherwise. The operators takes no parameters.

The syntax is

 is_closed()


Tag Value and Generic Value Operators

The tag operator returns the value of the tag of the given key. The is_tag operator returns "1" if the given element has a tag with this key and "0" otherwise. They only can be called in the context of an element.

Their syntax is

 t[<Key name>]

resp.

 is_tag(<Key name >)

The <Key name> must be in quotation marks if it contains special characters.

The tag operator can also be called with a substatement. Its syntax is then

 t[<Substatement>]

The generic tag operator returns the value of the tag of the key it is called for. It only can be called in the context of an element. In addition, it must be part of the value of a generic property to have its key specified.

Its syntax is

 ::


All Keys Evaluator

The all keys evaluator returns a container of the keys of the given element.

Its syntax is

 keys()


Geometry Related Operators

Geometry

since v0.7.55

The geometry operator returns the geometry of a single object as a geometry that can be put into the other geometry converting operators.

Its syntax is:

 geom()


Length

since v0.7.55

length() returns the length of an element, in meters, expressed as a floating point number. For ways, length() is measured along the path from the way's first node to its last node. For relations, length() is the sum of the lengths of all relation members of type way, regardless of their roles. For nodes, this evaluator will always return 0.

Metadata evaluators

Metadata evaluators return extended information about elements.

version

since v0.7.55

version() returns the version number (a positive whole number) of the element as it is stored in the OpenStreetMap database.

timestamp

since v0.7.55

timestamp() returns the ISO 8601 timestamp of the given element at the date and time it was last edited, as a string, in the format YYYY-MM-DDThh:mm:ssZ.

changeset

since v0.7.55

changeset() returns the changeset number (a positive whole number) in which the given element has been last edited.

uid

since v0.7.55

uid() returns the OpenStreetMap uid (a positive whole number) of the user that has last edited the given element.

user

since v0.7.55

user() returns the OpenStreetMap username of the user that has last edited the given element.

Count evaluators

count_* evaluators return a numerical count of items associated with an object. They cannot take an input set as an extra argument.

count_tags

since v0.7.54

count_tags() returns the number of tags on an object.

count_members

since v0.7.54

count_members() returns the number of member elements on an object:

  • For a relation, count_members() returns the number of members of the relation, regardless of those members' roles.
  • For a way, count_members() returns the number of nodes in the way.
  • For a node, count_members() always returns 0, since a node cannot have members.

count_distinct_members

since v0.7.55

count_distinct_members() returns the number of distinct member elements on an object:

  • For a relation, count_distinct_members() returns the number of unique members of the relation. If a member object is repeated in a relation, regardless of if the roles are different, the object will not be counted twice.
  • For a way, count_distinct_members() returns the number of unique nodes in the way. For a closed way, where the first and last node are the same, this node will not be counted twice.
  • For a node, count_distinct_members() always returns 0, since a node cannot have members.

count_by_role

since v0.7.55

count_by_role("<role>") only has meaning when run on a relation. It returns the number of relation members matching the role name <role>. To count the number of relation members without a role, use the argument string "".

count_distinct_by_role

since v0.7.55

count_distict_by_role("<role>") only has meaning when run on a relation. It returns the number of distinct relation members matching the role name <role>. To count the number of distinct relation members without a role, use the argument string "".

Usage examples

Evaluator Explanation
count_tags() == 0 Finds objects with zero tags
count_members() > 3 Finds relations with more than three members, or ways with more than three nodes
count_by_role("") > 0 Finds relations with one or more empty roles
Query statement Explanation
node(if: count_tags() == 0); Finds nodes with zero tags
way(if: count_members() > 100 ); Finds ways with more than 100 nodes
relation["type"="multipolygon"](if: count_by_role("outer") < 1); Finds multipolygon relations with less than one members of role outer

Point evaluator

The point evaluator, syntax pt(<latitude>, <longitude>), returns a valid OpenStreetMap node geometry. The geometry returned is a node at the latitude and longitude derived from the two given values. Each user supplied value, latitude and longitude, should parse as a valid floating point number.

  • latitude must fall within the range of -90 to 90, inclusive. Digits beyond 10e-7 (which is beyond the accuracy OpenStreetMap saves a node in) are ignored if within this range.
  • longitude must fall within the range of -180 to 180, inclusive. Digits beyond 10e-7 (which is beyond the accuracy OpenStreetMap saves a node in) are ignored if within this range.

Linestring evaluator

since v0.7.55

This operator always returns a geometry. The geometry is a line made of the points that are supplied as arguments.

Its syntax is

 lstr(<Evaluator>, <Evaluator>[, ...])


Polygon evaluator

This operator always returns a geometry. The geometry is a polygon made of the linestrings that are supplied as arguments. The polygon adheres to the right hand rule and has no self-intersections.

Its syntax is

 poly(<Evaluator>, <Evaluator>[, ...])


Aggregators

Aggregators need for execution both a set to operate on and an evaluator as argument. That evaulator will loop over each element of the set, and the aggregator will combine its results.


Union and Set

The basic syntax is

 <Set>.u(<Evaluator>)

resp.

 <Set>.set(<Evaluator>)

If the set is the default set _ then you can drop the set parameter:

 u(<Evaluator>)

resp.

 set(<Evaluator>)

These two evaluators execute their right hand side evulators on each element of the specified set. set makes a semi-colon separated list of all distinct values that appear. u returns the single found value if only one value is found. If no value is found then u returns an empty string. If multiple different values are found then set returns the text "< multiple values found >".


Min and Max

The basic syntax is

 <Set>.min(<Evaluator>)

resp.

 <Set>.max(<Evaluator>)

If the set is the default set _ then you can drop the set parameter:

 min(<Evaluator>)

resp.

 max(<Evaluator>)

These two evaluators execute their right hand side evaluators on each element of the specified set. If all return values are valid numbers then min returns the minimal amongst the numbers. Likewise, if all return values are valid numbers then max returns the maximal amongst the numbers. If not all return values are valid numbers then min returns the lexicographically first string. Likewise, if not all return values are valid numbers then max returns the lexicographically last string. If no value is found then each min and max return an empty string.


Sum

The basic syntax is

 <Set>.sum(<Evaluator>)

If the set is the default set _ then you can drop the set parameter:

 sum(<Evaluator>)

This evaluator executes its right hand side evaluators on each element of the specified set. If all return values are valid numbers then sum returns their sum. If not all return values are valid numbers then sum returns "NaN".

Statistical Count

This variant of the count operator counts elements of a given type in a set.

The syntax variants

 count(nodes)
 count(ways)
 count(relations)
 count(deriveds)

counts elements in the default set _, and the syntax variant

 <Set>.count(nodes)
 <Set>.count(ways)
 <Set>.count(relations)
 <Set>.count(deriveds)

counts elements in the set <Set>.


Union of Geometry

since v0.7.55

The basic syntax is

 <Set>.gcat(<Evaluator>)

If the set is the default set _ then you can drop the set parameter:

 gcat(<Evaluator>)

The evaluator executes its right hand side evaluator on each element of the specified set. It then combines the obtained geometries in one large object. If geometries are contained multiple times in the group then they are as well repeated as members of the result.


Unary Operators

Unary operators need for execution an operand. They are always written in prefix notation. The operators can be grouped with parentheses: The two variants

 <Operator><Evaluator>

and

 (<Operator><Evaluator>)

have as standalone expressions precisely the same semantics. The parenthesis variant exists to override operator precedence.

The order of precedence is as follows, ordered weak to strong binding:

  • logical disjunction
  • logical conjunction
  • equality, inequality
  • less, less-equal, greater, greater-equal
  • plus, binary minus
  • times, divided
  • logical negation
  • unary minus

In the following, the operators are ordered by precedence, stronger binding last.


Boolean Negation

The boolean negation evaluates to "1" if its argument evaluates to a representation of boolean false. Otherwise it evaluates to "1". Representations of boolean false are the empty std::string and every std::string that is a numerical representation of zero. Every other std::string represents boolean true.

Its syntax is

 ! <Evaluator>

The whitespace is optional.


Unary minus

The unary minus operator negates its argument. If the argument is an integer or a floating point number then it is negated as integer resp. floating point number. Otherwise the unary minus operator returns "NaN".

The syntax for unary minus is:

 - <Evaluator>

The whitespace is optional.


Binary Operators

Binary operators need for execution two operands. They are always written in infix notation. The operators can be grouped with parentheses: The two variants

 <Evaulator><Operator><Evaluator>

and

 (<Evaulator><Operator><Evaluator>)

have as standalone expressions precisely the same semantics. The parenthesis variant exists to override operator precedence:

 2 + 3 * 4

is evaluated to 2 + 12, then finally 14.

 (2 + 3) * 4

is evaluated to 5 * 4, then finally 20.

The order of precedence is as follows, ordered weak to strong binding:

  • the ternary operator
  • logical disjunction
  • logical conjunction
  • equality, inequality
  • less, less-equal, greater, greater-equal
  • plus, binary minus
  • times, divided
  • logical negation
  • unary minus

In the following, the operators are ordered by precedence, stronger binding last.


Boolean Disjunction

The boolean disjunction evaluates to "1" if one or both of its arguments evaluate to a representation of boolean true. Otherwise it evaluates to "0". Representations of boolean false are the empty string and every string that is a numerical representation of zero. Every other string represents boolean true. Currently, both arguments are always evaluated. This may change in future versions.

Its syntax is

 <Evaluator> || <Evaluator>

The whitespace is optional.


Boolean Conjunction

The boolean conjunction evaluates to "1" if both of its arguments evaluate to a representation of boolean true. Otherwise it evaluates to "0". Representations of boolean false are the empty string and every string that is a numerical representation of zero. Every other string represents boolean true. Currently, both arguments are always evaluated. This may change in future versions.

Its syntax is

 <Evaluator> && <Evaluator>

The whitespace is optional.


Equality and Inequality

The equaliy operator evaluates to "1" if both of its arguments are equal. Otherwise it evaluates to "0". The inequality operator evaluates to "0" if both of its arguments are equal. Otherwise it evaluates to "1". If both arguments can be interpreted as integers then the represented values are compared. Otherwise, if both arguments can be interpreted as floating point numbers then the represented values are compared. In all other cases the arguments are treated as strings.

Its syntax is for equality

 <Evaluator> == <Evaluator>

and for inequality

 <Evaluator> != <Evaluator>

The whitespace is optional.


Less, Less-Equal, Greater, and Greater-Equal

These operators evaluate to "1" if their arguments compare respectively. Otherwise they evaluate to "0". If both arguments can be interpreted as integers then the represented values are compared. Otherwise, if both arguments can be interpreted as floating point numbers then the represented values are compared. In all other cases the arguments are treated as strings.

The syntaxes for less, less-equal, greater, and greater-equal in this order are

 <Evaluator> < <Evaluator>
 <Evaluator> <= <Evaluator>
 <Evaluator> > <Evaluator>
 <Evaluator> >= <Evaluator>

The whitespace is optional.


Plus and Minus

While both operators have the same priority, they accept different kinds of arguments. If the arguments are both integers then they are added resp. subtracted as integers. If the arguments are both floating point numbers then they are added resp. subtracted as floating point numbers. Otherwise the plus operator concatenates the arguments as strings. Opposed to this, the minus operator returns "NaN".

The unary minus is an operator distinct from the binary minus operator defined here. It has a higher priority.

The syntaxes for plus and minus in this order are

 <Evaluator> + <Evaluator>
 <Evaluator> - <Evaluator>

The whitespace is optional.


Times and Divided

The times operator and the divided operator perform the respective arithmetic operations. If the arguments are both integers then they are multiplied as integers. Otherwise, if the arguments are both floating point numbers then they are multiplied resp. divided as floating point numbers. Division does treat integers like floating point numbers. If one or both arguments are no numbers then both the operators return "NaN".

The syntaxes for plus and minus in this order are

 <Evaluator> * <Evaluator>
 <Evaluator> / <Evaluator>

The whitespace is optional.


The Ternary Operator

The ternary operator needs for execution three operands. If the first operand evaluates to boolean true then it evaluates to what the second operand evaluates. Otherwise it evaluates to what the third operand evaluates.

The two variants

 <Evaulator>?<Evaluator>:<Evaluator>

and

 (<Evaulator>?<Evaluator>:<Evaluator>)

have as standalone expressions precisely the same semantics. The parenthesis variant exists to override operator precedence. For the precendence, see the binary operators.


String Endomorphisms

String endomorphisms are functions with one argument. Many of them help to normalize or check the value of its argument. They always first let their argument be evaluated. Their syntax is always

 <Function Name>(<Evaluator>)


Number Check, Normalizer and Suffix

The function number turns its argument into a number. If its argument starts with a number then number returns that number in a normalized format. Otherwise it returns "NaN". The function is_number checks whether its argument starts with a number. It returns "1" if its argument can be parsed as a number and "0" otherwise. The function suffix returns the suffix if any after the number in its argument. If the argument does not start with a number then it returns the empty string.

Their syntaxes are

 number(<Evaluator>)

resp.

 is_number(<Evaluator>)

resp.

 suffix(<Evaluator>)


Date Check and Normalizer

The function date turns its argument into a number representing a date. If its argument is a date then date returns the number representing its argument's value. Otherwise it returns "NaD". The function is_date checks whether its argument represents a date. It returns "1" if its argument can be parsed as a date and "0" otherwise.

A string is parsed for a date as follows:

  • the first group of digits is understood as year
  • the next group of digits if present is understood as month
  • then the next group if present is understood as day
  • if more groups of digits are present then they are understood as hour, minute, second

To be a date the year must be bigger than 1000, the month if present less or equal 12, the day if present less or equal 31, the hour if present less or equal 24, and the minute and second if present less or equal 60.

The date parser may get more liberal in future versions and accept more representations of dates.

The functions' syntaxes are

 date(<Evaluator>)

resp.

 is_date(<Evaluator>)


Geometry Endomorphisms

Geometry endomorphisms are functions with one argument. Many of them help to normalize or check the value of its argument. They always first let their argument be evaluated. Their syntax is always

 <Function Name>(<Evaluator>)


Center

since v0.7.55

The function center returns the center of its argument. It expects a function that evaluates to a geometry. It then delivers the point that is at the center of the bounding box of the geometry.

Its syntax is

 center(<Evaluator>)


Trace

since v0.7.55

The function trace returns the trace of its argument. It expects a function that evaluates to a geometry. It then delivers a collection of all segments and nodes that appear in its input. Ways are split at points that are explicitly in the set and at points that belong to more than one way in the set. Every node and segment is contained at most once.

Its syntax is

 trace(<Evaluator>)


Hull

since v0.7.55

The function hull returns the convex hull of its argument. It expects a function that evaluates to a geometry It then delivers a polygon without holes that contains all of its arguments.

Its syntax is

 hull(<Evaluator>)


List Represented Set Operators

Sometimes there is a need to represent multiple values in a tag's value. Although by no means mandated by the data format, the de-facto solution is to represent a set of values by a a semi-colon separated list of those values.

This section offers some functions to make handling of these lists easier. Currently, the delimiter is hard-coded to a semi-colon. For the sake of simplicity, leading or trailing white space at each list entry is ignored.

Note also that the lists are understood as sets. This means that the order of list elements does no matter.


List Represented Set Theoretic Operators

lrs_in

since v0.7.55

The function lrs_in returns "1" if its first argument is contained in the second argument treated as set. It returns "0" otherwise.

The function's syntax is

 lrs_in(<Evaluator>, <Evaluator>)
lrs_isect

since v0.7.55

The function lrs_isect returns the intersection of its two arguments treated as sets. If the arguments have no values in common then the empty string is returned.

The function's syntax is

 lrs_isect(<Evaluator>, <Evaluator>)
lrs_union

since v0.7.55

The function lrs_union returns the union of its two arguments treated as sets.

The function's syntax is

 lrs_union(<Evaluator>, <Evaluator>)


List Represented Set Statistic Operators

lrs_min

since v0.7.55

The function lrs_min returns the minimum of the elements in its argument treated as set. If all entries are numbers then the comparsion is numerical.

The function's syntax is

 lrs_min(<Evaluator>)
lrs_max

since v0.7.55

The function lrs_max returns the maximum of the elements in its argument treated as set. If all entries are numbers then the comparsion is numerical.

The function's syntax is

 lrs_max(<Evaluator>)


Set Key-Value Evaluator

Sets can have not only members. The may get assigned properties by other statements.

An example is the property "val": This property contains inside a "for"-loop the respective value of the current loop.

The syntax is

 <Set>.<Property>

As opposed to most other situations, it is mandatory to explicitly state the set.

Special syntax

Comments

Overpass QL allows comments in the same style of C, C++, Javascript, or CSS source code:

  out; // A single line comment
  /* Comments starting with slash asterisk must always be closed with an asterisk slash. */
  /* But they can span
         multiple lines. */

Extended Overpass Turbo Queries

Extended Overpass Turbo Queries are not part of the Overpass QL language specification. However, Overpass QL is a core component of code generated by the Overpass Turbo Query Wizard, and knowing about the shortcuts Extended Overpass Turbo Queries provide is useful when querying an Overpass Turbo server. It is likely that you will at some point run into this syntax when viewing examples of Overpass Turbo queries.

Extended Overpass Turbo Queries may be identified by double braces, {{ }}. For a full list of these queries and their purposes, see Extended Overpass Turbo Queries.

One of these, to give an example, {{data:overpass,server=http://dev.overpass-api.de/api_mmd/}}, is used to direct a query to the Overpass API development instance and its current code branch.

Escaping

The following C-style escape sequences (also defined in Javascript) for representing characters are recognized:

  • \n escapes a newline
  • \t escapes a tabulation
  • \" or \' escapes the respective quotation mark
  • \\ escapes the backslash
  • \u#### (the hash characters stand for four hexadecimal digits) escapes the respective unicode UTF-16 code unit, see Unicode escape sequences.
    Note that the database encodes characters in UTF-8 on 1 byte (only characters in the 7-bit US-ASCII characters subset in the range U+0000..U+007F) or more. All characters that that are assigned a Unicode scalar value in the standard 17 planes are encoded as UTF-8.
    However, this syntax only supports characters assigned in the BMP (Basic Multilingual Plane), excluding surrogates which are not Unicode characters and have no valid UTF-8 encoding (even if code points assigned to surrogates have a 16-bit scalar value). Non-ASCII characters in the BMP are encoded with UTF-8 on 2 bytes (in the range U+0080..U+07FF), or 3 bytes (in the range U+0800..U+FFFF, minus surrogates in the range U+D800..U+DFFF).
    Unicode characters outside the BMP can be represented in UTF-16 as a pair of surrogates: only valid pairs of UTF-16 surrogates (a high surrogate in U+D800..U+DBFF immediately followed by a low surrogate in U+DC00..U+DFFF) are convertible to UTF-8 in the database, and can be escaped as \uD###\uD### (the result of escaping invalid pairs of surrogates or unpaired surrogates is undefined); these valid escaped pairs of surrogates will be internally converted to UTF-8-encoded sequences of 4 bytes (in supplementary planes 1 to 16); characters in the last valid supplementary planes 15 and 16, assigned only for private use, are supported but not useful in OSM data as they are not interoperable.

In general, there is currently no support for the common escaping syntax \U000##### used in modern C to represent a codepoint in any one of the 17 valid Unicode planes (excluding surrogates), and not even for arbitrary 8-bit bytes with the common escaping syntax \x## (defined in C independantly of the encoding used). As much as possible escaping should be avoided if it's not needed, and valid UTF-8 used directly in requests.

As of July 2017, the development Overpass API instance allows the use of ICU regular expressions, which do support \\U000##### escapes. ICU support on this endpoint is experimental. ICU regular expressions are not, and may never be part of the official Overpass API. This feature may be discontinued at any time without prior notice. To enable this functionality, use the [regexp:ICU]; setting as part of your settings statement, and use the development API endpoint at http://dev.overpass-api.de/api_mmd/. If you are using the Overpass Turbo frontend, you must add the {{data:overpass,server=http://dev.overpass-api.de/api_mmd/}} Extended Overpass Turbo Queries at the end of your code to use the development Overpass API instance. With this addition, other ICU-supported escapes are recognized (using double backslashes in Overpass QL regular expressions), including \\p{Unicode property name} which will match any Unicode character having the specified Unicode property. Here is an example query that finds CJK characters outside the Basic Multilingual Plane. See the blog post and the GitHub issue tracking this potential feature.

Misc features

Map way/relation to area (map_to_area)

The map_to_area statement maps OSM object ids for both ways and relations to their Overpass API area id counterpart.

This is done by applying the following mapping rules inside Overpass API:

  • For ways: add 2400000000 to the way's OSM id
  • For relations: add 3600000000 to the relations's OSM id.

Example:

  rel(62716);
  out;              // output relation 62716
  map_to_area;      // map OSM relation to Overpass API area by adding 3600000000 to its id
  out;              // output area 3600062716

The main use case of this statement is to search for objects inside an area, which is again inside another area ("area in area query").

Notes:

  • The Overpass API internal area creation job does not create an area for each and every way/relation in OSM. If an area does not exist for a given way/relation, map_to_area will simply skip this object without adding an area. Otherwise the area will be returned but with its geometry as it was when it was last created or updated by an internal background process on the Overpass server, and it may be different from the most recent geometry loaded from the way/relation element in the OSM database.
  • Using areas in queries instead of actual OSM elements may speed up the Overpass queries as these geometries don't need to be fully loaded from possibly many child elements from the OSM database, and then converted by connecting ways with common nodes.
  • Also not all relations and ways may convert to a valid area (even if their tags normally imply that they should be valid areas) if they don't create properly closed rings.

The following examples outline some possible use cases for this statement:

Example 1: Find all pubs in the inner city of Cologne

Querying only for an area named "Innenstadt" would return quite a number of areas, not limited to Cologne.

try it yourself in overpass-turbo
area[name="Köln"]->.b;
rel(area.b)[name="Innenstadt"];
map_to_area -> .a;
node(area.a)[amenity=pub];
out meta;

Example 2: Find all counties in Hessen without fire station

try it yourself in overpass-turbo
area[admin_level=4]["name"="Hessen"][boundary=administrative]->.boundaryarea;
( node(area.boundaryarea)["amenity"="fire_station"];
  way(area.boundaryarea)["amenity"="fire_station"];
  >;
) ->.a;

.a is_in -> .b; 
area.b[admin_level=8] -> .bf; 

rel(area.boundaryarea)[admin_level=8];
map_to_area -> .bllf;

(.bllf - .bf );
rel(pivot);
(._;>;);
out;

Example 3ː Count the number of pharmacies per county

try it yourself in overpass-turbo
[out:csv(::"type",::"id", name, admin_level,::"count")];
area[name="Saarland"][boundary];
 rel(area)[boundary][admin_level=6];
 map_to_area;
 foreach->.d(
   (.d;);out; 
   (node(area.d)[amenity=pharmacy];
    way(area.d)[amenity=pharmacy];
    relation(area.d)[amenity=pharmacy];);
   out count;
 );

Example 4ː Named input set

try it yourself in overpass-turbo
rel(62716)->.b;
  .b out;
  .b map_to_area;
  out;

See Also